|
 Toolbar
Toolbar  控件包含一个 Button
对象集合，该对象被用来创建与应用程序相关联的工具栏。
语法：Toolbar
说明：
一般来说，工具栏包含一些按钮，这些按钮与应用程序菜单中各项的按钮对应，工具栏为用户访问应用程序的最常用功能和命令提供了图形接口。
有了 Toolbar 控件，就可以通过将 Button 对象添加到 Buttons 集合中来创建工具栏。每个 Button
对象都可有可选的文本或一幅图象，或者兼而有之，这些都是由相关联的 ImageList 控件提供的。可在一个按钮上用 Image
属性为每个 Button 对象加一幅图象，或用 Caption 属性显示文本，或者二者兼而有之。在设计时可用 Toolbar
控件的属性页将 Button 对象添加到控件中。在运行时可用 Add 和 Remove 方法添加按钮或从 Buttons
集合中删除按钮。
为了给 Toolbar 编程，将代码添加到 ButtonClick 事件中，以便对已选定的按钮作出反应。也可用 Style
属性确定每个 Button 对象的状态和外观。例如，如果已对四个按钮赋以 ButtonGroup
样式，则在任何时候只能按下一个按钮，而且至少总有一个按钮已被按下。
可对 Button 对象赋以 PlaceHolder
样式，然后将控件定位在定位符的上方，从而在工具栏上为其它控件创建空间。例如，在设计时，为将下拉组合框放置在工具栏上，用
PlaceHolder 样式添加一个 Button 对象，并调整其大小使之与 ComboBox 控件一样宽。然后将
ComboBox 控件放置在定位符上。
在运行时双击工具栏后就会调用“自定义工具栏”对话框，有了这个对话框，用户就可隐藏、显示或重新安排工具栏按钮。可用
AllowCustomize 属性来允许或禁用对话框。也可用 Customize
方法调用“自定义工具栏”对话框。如果希望保存或恢复工具栏的状态，或者允许用户这样做，则有两种方法可供使用：SaveToolbar
和 RestoreToolbar 方法。在改动工具栏时产生的 Change 事件一般被用来调用 SaveToolbar 方法。
注意 自定义的对话框也包含帮助按钮。当终端用户单击帮助按钮时，使用 HelpFile 和 HelpContextID
属性来决定显示哪个帮助文件。
通过对每个 Button 对象的 ToolTipText 描述进行编程可进一步增强可用性。为显示工具提示，必须将
ShowTips 属性设置为
True。当用户调用“自定义工具栏”对话框时，单击按钮就会导致在对话框中显示按钮的描述；这种描述可通过设置
Description 属性来编程实现。
发行注意 Toolbar 控件是一组ActiveX 控件的一部分，这组自定义控件可在文件 MSCOMCTL.OCX
中找到。为在应用程序中使用 Toolbar 控件，必须将文件 MSCOMCTL.OCX 添加到工程中。在发行应用程序时，应将文件
MSCOMCTL.OCX 安装到用户的 Microsoft Windows 的SYSTEM 或 System32 (
Windows NT 平台上)的文件夹。
例：该示例用 Add 方法将 Button 对象添加到 Toolbar 控件中去，并分配 ImageList
控件所提供的图象。每个按钮的状态都由 Style
属性决定。下述代码创建了能够用来打开和保存文件的按钮，并包含了一个用来改变窗体背景的 ComboBox 控件。要试用此例，将
Toolbar 控件，ImageList 控件和 ComboBox 控件放置到窗体上，并把代码粘贴到窗体的声明部分。要确保将
ComboBox 直接插入到 Toolbar 控件上。运行此例，单击不同按钮并从组合框中进行选择。
Private Sub Form_Load()
'为 ImageList 创建对象变量。
Dim imgX As ListImage
'将图片加载到 ImageList 控件中。
Set imgX = ImageList1.ListImages. _
Add(, "open", LoadPicture("Graphics\bitmaps\tlbr_w95\open.bmp"))
Set imgX = ImageList1.ListImages. _
Add(, "save", LoadPicture("Graphics\bitmaps\tlbr_w95\save.bmp"))
Toolbar1.ImageList = ImageList1
'为 Toolbar 创建对象变量。
Dim btnX As Button
'用 Add 方法将按钮对象添加到 Buttons 集合中。创建
'每个按钮后，设置 Description 和 ToolTipText 属性。
Toolbar1.Buttons.Add , , , tbrSeparator
Set btnX = Toolbar1.Buttons.Add(, "open", , tbrDefault, "open")
btnX.ToolTipText = "Open File"
btnX.Description = btnX.ToolTipText
Set btnX = Toolbar1.Buttons.Add(, "save", , tbrDefault, "save")
btnX.ToolTipText = "Save File"
btnX.Description = btnX.ToolTipText
Set btnX = Toolbar1.Buttons.Add(, , , tbrSeparator)
'下一个按钮具有 Placeholder 属性。ComboBox 控件
'将被放置在按钮的上方。
Set btnX = Toolbar1.Buttons.Add(, "combo1", , tbrPlaceholder)
btnX.Width = 1500 '容纳一个 combobox 的占位符宽度。
Show '显示窗体以继续配置 ComboBox。
'配置 ComboBox 控件，使其跟具有 PlaceHolder 样式
'(key = "combo1") 的 Button 对象在相同位置。
With Combo1
.Width = Toolbar1.Buttons("combo1").Width
.Top = Toolbar1.Buttons("combo1").Top
.Left = Toolbar1.Buttons("combo1").Left
.AddItem "Black" '为文本添加颜色。
.AddItem "Blue"
.AddItem "Red"
.ListIndex = 0
End With
End Sub
Private Sub Form_Resize()
'配置 ComboBox 控件。
With Combo1
.Width = Toolbar1.Buttons("combo1").Width
.Top = Toolbar1.Buttons("combo1").Top
.Left = Toolbar1.Buttons("combo1").Left
End With
End Sub
Private Sub toolbar1_ButtonClick(ByVal Button As Button)
'用 Key 属性和 SelectCase 语句来指定一个动作。
Select Case Button.Key
Case Is = "open" '打开文件。
MsgBox "Add code to open file here!"
Case Is = "save" '保存文件。
MsgBox "Add code to save file here!"
End Select
End Sub
Private Sub Combo1_Click()
'用 ComboBox 改变窗体的背景。
Select Case Combo1.ListIndex
Case 0
Form1.BackColor = vbBlack
Case 1
Form1.BackColor = vbBlue
Case 2
Form1.BackColor = vbRed
End Select
End Sub
TreeView
TreeView 控件显示 Node 对象的分层列表，每个 Node 对象均由一个标签和一个可选位图组成。TreeView
一般用于显示文档标题、索引入口、磁盘上的文件和目录、或能被有效地分层显示的其它种类信息。
语法：Treeview
说明：
创建了 TreeView 控件之后，可以通过设置属性与调用方法对各 Node
对象进行操作，这些操作包括添加、删除、对齐和其它操作。可以编程展开与折回 Node
对象来显示或隐藏所有子节点。Collapse、Expand 和 NodeClick 三个事件也提供编程功能。
Node 对象使用 Root、Parent、Child、FirstSibling、Next、Previous 和
LastSibling 属性。在代码中可通过检索对 Node 对象的引用，从而在树上定位。也可以使用键盘定位。UP ARROW
键和 DOWN ARROW 键向下循环穿过所有展开的 Node 对象。从左到右、从上到下地选择 Node
对象。若在树的底部，选择便跳回树的顶部，必要时滚动窗口。RIGHT ARROW 键和 LEFT ARROW 键也穿过所有展开的
Node 对象，但是如果选择了未展开的 Node之后再按 RIGHT ARROW 键，该 Node
便展开；第二次按该键，选择将移向下一个 Node。相反，若扩展的 Node 有焦点，这时再按 LEFT ARROW 键，该
Node 便折回。如果按下 ANSI 字符集 中的键，焦点将跳转至以那个字母开头的最近的
Node。后续的按该键的动作将使选择向下循环，穿过以那个字母开头的所有展开节点。
控件的外观有八种可用的替换样式，它们是文本、位图、直线和 +/- 号的组合，Node 对象可以任一种组合出现。
TreeView 控件使用由 ImageList 属性指定的 ImageList 控件，来存储显示于 Node
对象的位图和图标。任何时刻，TreeView 控件只能使用一个 ImageList。这意味着，当 TreeView 控件的
Style 属性被设置成显示图像的样式时，TreeView 控件中每一项的旁边都有一个同样大小的图像。
发行注意 TreeView 控件是 MSCOMCTL.OCX 文件中的一组 ActiveX 控件的一部分。为了在应用程序中使用
TreeView 控件，必须将 MSCOMCTL.OCX 文件添加到工程中。在发行应用程序时，要在用户的 Microsoft
Windows System 或 System32 目录中安装 MSCOMCTL.OCX 文件。
|
工具栏（