|
 Stretch
返回或设置一个值，该值用来指定一个图形是否要调整大小，以适应与 Image 控件的大小。
语法：
object.Stretch [= boolean]
Boolean 一个用来指定是否要调整图形的大小的布尔表达式，按照设置值的描述。
boolean 的设置值为：
True 表示图形要调整大小以与控件相适合。
False （缺省值）表示控件要调整大小以与图形相适。
说明：
如果 Stretch 被设置为 True，那么，控件大小的调整使得它所包含的图形的大小也要调整。
例：本例从一个图标目录将一个箭头图标装入 Image 控件。当 Stretch 属性设置为 True
时，该箭头将缓慢地移过窗体，而当 Stretch 属性设置为 False
时，该箭头将跳跃式通过窗体。要试用此例，先将下面的代码粘贴到包含一个 Image 控件、一个 CheckBox 控件、以及一个
Timer 控件的窗体的声明部分，然后按 F5 键 并单击该窗体。应确认图标目录所在的路径，必要时可以改变。单击
CheckBox，然后再次单击窗体，就可以看到 Stretch 属性的影响。
Dim ImgW ' 声明变量。
Private Sub Form_Load ()
' 将图标装入 Image 控件。
Image1.Picture = LoadPicture("ICONS\ARROWS\ARW02RT.ICO")
Image1.Left = 0 ' 将图象移动到左部边界处。
ImgW = Image1.Width ' 保存图象的宽度。
Timer1.Interval = 300
Timer1.Enabled = False ' 关闭计时器。
Check1.Caption = "Stretch Property"
End Sub
Private Sub Form_Click ()
Timer1.Enabled = True ' 打开计时器。
End Sub
Private Sub Timer1_Timer ()
Static MoveIcon As Integer ' 移动图标的标志。
If Not MoveIcon Then
Image1.Move Image1.Left + ImgW, Image1.Top, ImgW * 2
Else
' 移动图象并使它返回原来的宽度。
Image1.Move Image1.Left + ImgW, Image1.Top, ImgW
End If
' 如果图象在窗体的边界之外，那么将导致结束。
If Image1.Left > ScaleWidth Then
Image1.Left = 0
Timer1.Enabled = False
End If
MoveIcon = Not MoveIcon ' 复位标志。
End Sub
Private Sub Check1_Click ()
Image1.Stretch = Check1.Value
End Sub
|
