|
OLEDrag
引起部件初始化 OLE 拖放操作。
语法：object.OLEDrag
说明：
当调用 OLEDrag 方法时，部件的 OLEStartDrag 事件发生，允许向目标部件提供数据。
Overlay
从一个 ListImages 集合绘制一幅图象，叠加在另一幅上面，并返回结果。
语法：
object.Overlay (index1, index2)
index1 必需的。一个整数（Index 属性）或唯一的字符串（Key 属性），它指定了将被叠加的图象。
index2 必需的。一个整数（Index 属性）或唯一字符串（Key 属性），它指定了将被绘制在由 index1
指定的对象上的图象。该图象中与 MaskColor
属性匹配的颜色被设置成透明的。如果没有任何颜色与之匹配，该图象将不透明地绘制在其它图象上。
说明：
Overlay 方法连同 MaskColor 属性一起使用，将两幅根本不同的图象创建成一幅单一图象。Overlay
方法把一幅位图强加到另一幅位图之上创建了第三幅图象，也就是复合图象。MaskColor 属性决定了叠加图象的哪种颜色是透明的。
index 可以是一个索引，也可以是一个关键字。例如，用集合中的第二幅图片叠加第一幅图片，可以这样做：
Set Picture1.Picture = ImageList1.Overlay(1,2) '通过 Index 引用。
'或者通过 Key 属性引用。
Set Picture1.Picture = ImageList1.Overlay("First", "Second")
例：本例把五幅 ListImage 对象加载到 ImageList 控件中，并在两个 PictureBox
控件中显示任意两幅图象。对于每个 PictureBox，从两个 ComboBox
控件之一选择一幅图象来显示。当单击窗体时，代码用 Overlay 方法创建第三幅图象并显示在第三个 PictureBox
控件中。要试用此例，把一个 ImageList 控件、两个 ComboBox 控件和三个 PictureBox
控件放置在同一窗体上，把代码粘贴到该窗体的声明部分。运行此例，并单击窗体。
Private Sub Form_Load()
Dim X As ListImage
'把五幅图象添加到 ListImages 集合中。
Set X = ImageList1.ListImages. _
Add(, , LoadPicture("icons\elements\moon05.ico"))
Set X = ImageList1.ListImages. _
Add(, , LoadPicture("icons\elements\snow.ico"))
Set X = ImageList1.ListImages. _
Add(, , LoadPicture("icons\writing\erase02.ico"))
Set X = ImageList1.ListImages. _
Add(, , LoadPicture("icons\writing\note06.ico"))
Set X = ImageList1.ListImages. _
Add(, , LoadPicture("icons\flags\flgfran.ico"))
With combo1 '置于第一个 ComboBox 控件中。
.AddItem "Moon"
.AddItem "Snowflake"
.AddItem "Pencil"
.AddItem "Note"
.AddItem "Flag"
.ListIndex = 0
End With
With combo2 '置于第二个 ComboBox 控件中。
.AddItem "Moon"
.AddItem "Snowflake"
.AddItem "Pencil"
.AddItem "Note"
.AddItem "Flag"
.ListIndex = 2
End With
Picture1.BackColor = vbWhite '使 BackColor 为白色。
Picture2.BackColor = vbWhite
Picture3.BackColor = vbWhite
End Sub
Private Sub Form_Click()
'叠加两个图象，并在 PictureBox3 中显示。
Set Picture3.Picture = ImageList1. _
Overlay(combo1.ListIndex + 1, combo2.ListIndex + 1)
End Sub
Private Sub combo1_Click()
'改变 PictureBox 以反映 ComboBox 的选择。
Set Picture1.Picture = ImageList1. _
ListImages(combo1.ListIndex + 1).ExtractIcon
End Sub
Private Sub combo2_Click()
'改变 PictureBox 以反映 ComboBox 的选择。
Set Picture2.Picture = ImageList1. _
ListImages(combo2.ListIndex + 1).ExtractIcon
End Sub
|
